CU Amiga Super CD-ROM 17/CU Amiga Magazine's Super CD-ROM 17 (1997)(EMAP Images)(GB)[!][issue 1997-12].iso/CoolWB/Icons/Other/RareDiamonds/DoIcon12/Install-DoIcon

Text File | 1994-11-12 | 5KB | 225 lines

; $VER: DoIcon-Install 1.2 (12.11.94)
; Install script for DoIcon © 1994 by Lars 'SFX' Eilebrecht

(set app_name "DoIcon")

(set version "1.2")

(set vers_name (cat app_name " v" version))

(set bad-kick "You must be using Kickstart 2.04+ to install DoIcon")

(set install-msg
  (cat
    "\n\nWelcome to the DoIcon installation utility.\n\n"
    "This program lets you install DoIcon on your Amiga.\n\n"
    "Please read the documentation befor using DoIcon.\n\n"
    "© 1994 by Lars Eilebrecht."
  )
)

(set exit_msg "\nDon't forget to read the documentation!\n\nHave a nice day...")

(set copying "Copying ")

(set were-doicon "Where would you like to install the Doicon-executable?")

(set help-were-doicon "You should place DoIcon in an directory which is in your search path, C: for example.")

(set install-guide "Would you like to install any DoIcon guides?")

(set help-were-guide
  (cat
    "    DoIcon.guide is the documentation for DoIcon in the special "
    "AmigaGuide® hypertext format. You need a program like AmigaGuide or "
    "MultiView to view it properly."
  )
)

(set which-guides "\n Which guides should be installed?")

(set which-language "\nWhich languages should be installed?")

(set which-language-help
  (cat
    "    The Amiga can be operated in many different languages. If you "
    "want DoIcon to use the same language as the Amiga Workbench "
    "then a catalog file must be copied to your harddisk for each "
    "language supported.\n"
    "    To reduce the amount of space consumed by the language files, "
    "you can select to have only the files of specific languages "
    "copied.\n"
    "    Simply check the boxes of the languages you wish to have "
    "available on your system.\n"
    "(Please note that the english language is builtin) "
  )
)

(transcript (cat "Installing " vers_name " ..."))

; Check Kickstart version. Exit if not at least 2.0

(if (< (/ (getversion) 65536) 37)
  (abort bad-kick)
)

(message install-msg)

(complete 0)

; Copy DoIcon

(set destination
  (askdir
    (prompt  were-doicon)
    (help    (cat help-were-doicon "\n\n" @askdir-help))
    (default "c:")
  )
)

(set @default-dest destination)

(copyfiles
  (prompt "Copying DoIcon...")
  (confirm)
  (source app_name)
  (dest destination)
  (help @copyfiles-help)
)

(complete 30)

; Copy guide

(if
  (askbool
    (prompt (cat "\n" install-guide))
    (help   help-were-guide)
  )

  (

    (set guidelang
      (askoptions
        (prompt which-guides)
        (help   (cat help-were-guide "\n\n\n" @askoptions-help))
        (choices
          "Deutsch"
          "English"
        )
        (default "English")
      )
    )

    (set n 0)

    (while
      (set language
        (select n
          "Deutsch"
          "English"
          ""
        )
      )

      (if (IN guidelang n)
            (

     (set destination
      (askdir
        (prompt  (cat "Select a place for the following guide: " language))
        (help    (cat help-were-guide "\n\n" @askdir-help))
        (default "Help:")
      )
    )

              (set guidesource (cat "Docs/" language  "/DoIcon.guide"))

              (set guidedestination destination)

              (if (exists guidesource)
                (
                  (copyfiles
                    (prompt (cat copying "DoIcon.guide..."))
                    (confirm)
                    (source guidesource)
                    (dest guidedestination)
                    (infos)
                    (help @copyfiles-help)
                  )
                )
              )
            )
          )

        (set n (+ n 1))
      )
    )
)

(complete 70)

; Copy catalog files

(if (= (exists "Locale:") 2)
  (
    (set lang
      (askoptions
        (prompt which-language)
        (help   (cat which-language-help "\n\n" @askoptions-help))
        (choices
          "English"
          "Deutsch"
          "Suomi"
        )
        (default 1)
      )
    )


    (set n 0)

    (while
      (set language
        (select n
          "English"
          "Deutsch"
          "Suomi"
          ""
        )
      )

      (
        (if (IN lang n)
          (if (<> 0 n)   ; skip english
            (
              (set catalogs (tackon "Locale" language))

              (set destination (tackon "Locale:Catalogs" language))

              (if (exists (tackon catalogs "DoIcon.catalog"))
                (copyfiles
                  (prompt "Copying catalogs...")
                  (confirm)
                  (source (tackon catalogs "DoIcon.catalog"))
                  (dest destination)
                  (help @copyfiles-help)
                )
              )

            )
          )
        )

      )
      (set n (+ n 1))
    )
  )
)

(complete 100)

(exit exit_msg)

; End of Installer script